Mantenimiento Industrial de Windows: Script .BAT de Alto Impacto
Como especialista con más de 20 años en hardware y sistemas Aspel, he perfeccionado este script para realizar una limpieza que los antivirus convencionales a veces ignoran. Esta herramienta utiliza fuerza bruta para inmovilizar amenazas en las carpetas de inicio y limpiar el rastro de malware.
🛡️ REQUISITO TÉCNICO: Este script requiere privilegios de Administrador para manipular el registro y las carpetas del sistema de forma segura.
Funcionalidades Técnicas:
- Inmovilización de Binarios: Renombra archivos sospechosos en Startup a .1exe y .1lnk para revisión manual.
- Depuración de Registro: Neutraliza llaves de inicio automático inyectando prefijos de seguridad.
- Optimización de Recursos: Limpieza profunda de Prefetch, Temp y cola de impresión.
@echo off
title SCRIPT_MANTENIMIENTO_EL_COMPUTAROLOGO
color 0b
:: 1. VERIFICACIÓN INMEDIATA DE PRIVILEGIOS
net session >nul 2>&1
if %errorLevel% neq 0 (
echo ====================================================
echo ERROR: DEBE EJECUTAR COMO ADMINISTRADOR.
echo HAGA CLIC DERECHO - EJECUTAR COMO ADMINISTRADOR.
echo ====================================================
pause
exit
)
:: 2. ADVERTENCIA Y CONSENTIMIENTO
echo ====================================================
echo ADVERTENCIA: ESTE SCRIPT CERRARA TODOS LOS
echo PROGRAMAS ACTIVOS PARA LIBERAR ARCHIVOS Y
echo REALIZAR UNA LIMPIEZA PROFUNDA DE TEMPORALES.
echo.
echo ASEGURESE DE HABER GUARDADO SU TRABAJO.
echo USUARIO ACTUAL: %username%
echo ====================================================
echo.
pause
echo.
echo APLICANDO FUERZA BRUTA Y LIMPIEZA (VERBOSE)...
echo ====================================================
echo.
echo.
echo [PASO 1] FORZANDO CIERRE DE NAVEGADORES Y APPS...
echo.
:: Cierre específico de navegadores (Árbol de procesos completo)
taskkill /F /IM chrome.exe /T >nul 2>&1
taskkill /F /IM firefox.exe /T >nul 2>&1
taskkill /F /IM msedge.exe /T >nul 2>&1
:: Cierre masivo de procesos de usuario (Protegiendo el script y el sistema)
taskkill /F /FI "USERNAME eq %username%" /FI "IMAGENAME ne explorer.exe" /FI "IMAGENAME ne cmd.exe" /FI "IMAGENAME ne dwm.exe" /FI "WINDOWTITLE ne SCRIPT_MANTENIMIENTO_EL_COMPUTAROLOGO"
echo.
echo [PASO 2] DESBLOQUEANDO ADMINISTRADOR DE TAREAS...
:: Habilita el Administrador de Tareas borrando la restriccion si existe
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\System" /v DisableTaskMgr /f >nul 2>&1
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\Policies\System" /v DisableTaskMgr /f >nul 2>&1
echo OK.
:: --- LIMPIEZA C:\Windows\Temp ---
echo [PASO 3] PROCESANDO: C:\Windows\Temp...
:: Quitamos atributos de sistema, oculto y solo lectura
attrib -r -a -s -h "C:\Windows\Temp\*" /s /d >nul 2>&1
del /s /f /q "C:\Windows\Temp\*.*"
for /d %%p in ("C:\Windows\Temp\*") do (
rd /s /q "%%p"
)
:: --- LIMPIEZA %temp% (USUARIO) ---
echo.
echo [PASO 4] PROCESANDO: Temporales de Usuario...
:: Quitamos atributos a los 5,000+ elementos
attrib -r -a -s -h "%temp%\*" /s /d >nul 2>&1
:: Borrado de archivos (incluye archivos sin extension con /a)
del /s /f /q /a "%temp%\*.*"
:: Borrado de carpetas
for /d %%p in ("%temp%\*") do (
rd /s /q "%%p"
)
:: --- LIMPIEZA PREFETCH ---
echo.
echo [PASO 5] PROCESANDO: C:\Windows\Prefetch...
attrib -r -a -s -h "C:\Windows\Prefetch\*" /s /d >nul 2>&1
del /s /f /q "C:\Windows\Prefetch\*.*"
for /d %%p in ("C:\Windows\Prefetch\*") do (
rd /s /q "%%p"
)
echo.
echo [PASO 6] DESHABILITANDO INICIO AUTOMATICO (RENOMBRANDO)...
:: Usamos -ErrorAction SilentlyContinue para ignorar llaves vacias
:: Usamos un filtro para asegurar que solo procese llaves con valores existentes
:: Técnica robusta: Extraemos las propiedades directamente sin pasar por Get-Member
:: Se incluye WOW6432Node y se agrega un 1 al inicio de la ruta sin renombrar la clave
powershell -Command "$llaves = @('HKCU:\Software\Microsoft\Windows\CurrentVersion\Run','HKCU:\Software\Microsoft\Windows\CurrentVersion\RunOnce','HKLM:\Software\Microsoft\Windows\CurrentVersion\Run','HKLM:\Software\Microsoft\Windows\CurrentVersion\RunOnce','HKLM:\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Run'); foreach($l in $llaves){ if(Test-Path $l){ $items = Get-ItemProperty $l; $items.PSObject.Properties | ForEach-Object { $n = $_.Name; $v = $_.Value.ToString(); if($n -notmatch '^(PSPath|PSParentPath|PSChildName|PSDrive|PSProvider|^$)'){ try { $nuevoValor = '1' + $v; Set-ItemProperty -Path $l -Name $n -Value $nuevoValor -ErrorAction SilentlyContinue } catch {} } } } }"
echo OK.
echo.
echo [PASO 7] INUTILIZANDO BINARIOS carpetas startup les agrega 1
echo ==========================================================
powershell -Command "$u = [System.Environment]::GetFolderPath('ApplicationData') + '\Microsoft\Windows\Start Menu\Programs\Startup\*'; $g = [System.Environment]::GetFolderPath('CommonApplicationData') + '\Microsoft\Windows\Start Menu\Programs\Startup\*'; Get-ChildItem -Path $u, $g -Include *.lnk, *.exe, *.bat, *.vbs, *.cmd, *.js, *.ps1 -ErrorAction SilentlyContinue | ForEach-Object { $nuevaExt = '.1' + $_.Extension.Replace('.', ''); try { Rename-Item -Path $_.FullName -NewName ($_.BaseName + $nuevaExt) -Force -ErrorAction SilentlyContinue } catch {} }"
echo.
echo OK. Se agrego 1 a la extension de cada archivo para revisar
echo.
echo [PASO 8] REINICIANDO Y LIMPIANDO COLA DE IMPRESION...
:: Detenemos el servicio para liberar los archivos .SHD y .SPL
net stop spooler >nul 2>&1
del /Q /F /S "%systemroot%\System32\Spool\Printers\*.*" >nul 2>&1
net start spooler >nul 2>&1
echo OK.
echo.
echo [PASO 9] LIMPIEZA DE CACHE WEB (PRESERVANDO CLAVES)...
:: Borra Archivos Temporales de Internet (Caché)
RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 8
:: Borra Cookies (Para liberar espacio y rastreadores)
RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 2
:: NOTA: No incluimos el 1 (Historial) ni el 16 (Formularios) ni el 32 (Contraseñas)
echo OK.
echo.
echo [PASO 10] ABRIENDO RUTAS PARA VERIFICACION...
echo ====================================================
:: 1. Abrir Regedit en la ruta de Inicio (HKCU)
:: Creamos un pequeño "salto" en el registro para que regedit abra en la ruta deseada
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Applets\Regedit" /v "LastKey" /d "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run" /f >nul 2>&1
start regedit.exe
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Applets\Regedit" /v "LastKey" /d "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Run" /f >nul 2>&1
:: 2. Abrir Carpetas de Temporales
start explorer.exe "C:\Windows\Temp"
start explorer.exe "%temp%"
start explorer.exe "C:\Windows\Prefetch"
:: 3. Abrir Carpetas de Inicio (Startup) para ver los .eje
start explorer.exe "%AppData%\Microsoft\Windows\Start Menu\Programs\Startup"
start explorer.exe "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Startup"
echo.
echo [INFO] Se han abierto las carpetas de limpieza y Regedit en la clave 'Run'.
echo.
:: TRUCO PARA PASAR EL CMD AL FRENTE
powershell -Command "$wshell = New-Object -ComObject WScript.Shell; $wshell.AppActivate((Get-Process -Id $pid).MainWindowTitle)"
:LOOP_PARPADEO
:: Color Rojo con letras blancas
color 4f
echo.
echo ============================================================
echo !!! ATENCION: PROCESO COMPLETADO CON EXITO !!!
echo ============================================================
echo.
echo RECUERDA QUE DEBES PASARLE UN ANTIVIRUS A TU COMPU:
echo.
echo ---^> AVG o MALWAREBYTES ^<---
echo.
echo ============================================================
echo PRESIONA [CTRL + C] PARA TERMINAR
echo ============================================================
:: Temporizador artesanal de 1 segundo
ping -n 2 127.0.0.1 >nul
:: Color Amarillo con letras negras
color 60
cls
echo.
echo ============================================================
echo !!! ATENCION: PROCESO COMPLETADO CON EXITO !!!
echo ============================================================
echo.
echo RECUERDA QUE DEBES PASARLE UN ANTIVIRUS A TU COMPU:
echo.
echo ---^> AVG o MALWAREBYTES ^<---
echo.
echo ============================================================
echo PRESIONA [CTRL + C] PARA TERMINAR
echo ============================================================
:: Temporizador artesanal de 1 segundo
ping -n 2 127.0.0.1 >nul
:: Regresa al inicio del bucle
cls
goto LOOP_PARPADEO
¡Mejor aún! Descárgalo AQUÍ →
Soporte técnico garantizado por el computarologo de cancun https://computarologo.com
¿Por qué usar este método?
A diferencia de las herramientas comerciales pesadas, este es un enfoque artesanal: código puro, sin frameworks innecesarios, que permite al técnico auditar visualmente el resultado final.
¿Necesitas soporte especializado?
"Si persisten las molestias... consulte al Computarólogo"
¿Tienes problemas con tu Aspel SAE, hardware legacy o una infección difícil?
Contactar por WhatsApp